Adding managed data fields

package
{
  import ilog.orgchart.OrgChartFields;
  import flash.events.Event;

  /**
   * This sample class shows how to add field mappings.
   */  
  public class ExtendedFields extends OrgChartFields
  {
    private var _salaryField:String = "salary";

    /**
     * @private
     */    
    public function set salaryField(value:String):void {
      if (_salaryField != value) {
        _salaryField = value;
        dispatchEvent(new Event(Event.CHANGE));
      }
    }

    [Inspectable (category="OrgChart", defaultValue="salary")]    
    /**
     * The name of the property chosen to determine the salary
     * of a person, if the <code>salaryFunction</code> is not set.
     * 
     * @default "salary"
     */     
    public function get salaryField():String {
      return _salaryField;
    }  
    
    private var _salaryFunction:Function = null;
    
    /**
     * @private
     */ 
    public function set salaryFunction(value:Function):void {
      if (_salaryFunction != value) {
        _salaryFunction = value;
        dispatchEvent(new Event(Event.CHANGE));
      }
    }
     
    /**
     * The function used to determine the salary of a person.
     * It must have the following signature:
     * <pre>
     * salaryFunction(<i>item:Object</i>):String
     * </pre>
     * This returns the salary from the
     * <code>item</code> provided by the data provider.
     * 
     * @default null
     */     
    public function get salaryFunction():Function {
      return _salaryFunction;
    }      
  }
}

package
{
  import ilog.orgchart.OrgChartItem;
  import mx.core.IUIComponent;

  /** 
   * This sample data item shows how to add a data field to the
   * <code>OrgChartItem</code>.
   */
  public class ExtendedDataItem extends OrgChartItem
  {
    public function ExtendedDataItem(owner:IUIComponent, item:Object,
                                     data:Object) {
      super(owner, item, data);
    }
   
    public function get salary():String {
      var fields:ExtendedFields = orgChart.fields as ExtendedFields;
      return getFieldValue(fields.salaryField, null,
                           fields.salaryFunction) as String;
    }
   }
 }

package
{
  import ilog.orgchart.OrgChart;
  import ilog.orgchart.OrgChartItem;

  /** 
   * This sample OrgChart shows how to use an OrgChartItem subclass.
   */
  public class ExtendedOrgChart extends OrgChart
  {
    override protected function createOrgChartItem(item:Object):OrgChartItem {
      var collection:IHierarchicalCollectionView = dataProvider as 
                                                   IHierarchicalCollectionView;
      var hData:IHierarchicalData = collection.source;
      return new ExtendedDataItem(this, item, hData.getData(item));
    }
  }
 }

package
{
  import ilog.orgchart.OrgChartItemRenderer;
  import ilog.orgchart.OrgChartItem;
  import mx.core.FlexTextField;

 /**
  * This sample item renderer shows how to add a field label to the
  * OrgChartItemRenderer
  */
  public class ExtendedItemRenderer extends OrgChartItemRenderer
  {
    
    private var _salaryLabel:FlexTextField;
    
    override protected function getFieldLabels():Array {
      var labels:Array = super.getFieldLabels();
      labels.push(_salaryLabel); 
      return labels;
    }
    
    override protected function applyData(data:OrgChartItem):void {
      _salaryLabel = setLabelProperty(_salaryLabel, "salary");
      super.applyData(data);            
    }
  }

package
{
  import ilog.orgchart.OrgChartDetailedItemRenderer;
  import mx.core.FlexTextField;
  import ilog.orgchart.OrgChartItem;

  /**
   * This sample item renderer shows how to add a field label to the
   * OrgChartDetailedItemRenderer 
   */  
  public class ExtendedDetailedItemRenderer extends OrgChartDetailedItemRenderer
  {        
    private var _salaryLabel:FlexTextField;
    private var _salaryLeftLabel:FlexTextField;
    
    override protected function createChildren():void {
      _salaryLeftLabel = new FlexTextField();
      addChild(_salaryLeftLabel);
      super.createChildren();      
    }
    
    override protected function setLeftLabelsText():void {
      super.setLeftLabelsText();
      if (_salaryLeftLabel != null) {
        _salaryLeftLabel.text = "Salary";                
      }
    }
    
    override protected function getFieldLabels():Array {
      var labels:Array = super.getFieldLabels();
      labels.push(_salaryLabel); 
      return labels;
    }
    
    override protected function getFieldValueLabels():Array {
      var labels:Array = super.getFieldValueLabels();
      labels.push(_salaryLeftLabel); 
      return labels;
    }
    
    override protected function applyData(data:OrgChartItem):void {
      _salaryLabel = setLabelProperty(_salaryLabel, "salary");
      super.applyData(data);
            
    }
  }
}